home *** CD-ROM | disk | FTP | other *** search
/ Sprite 1984 - 1993 / Sprite 1984 - 1993.iso / src / boot / netBoot.OpenProm / sun4c.md / start.s < prev   
Encoding:
Text File  |  1991-09-02  |  3.0 KB  |  126 lines
  1. !
  2. ! The following variable MUST be the first thing in this
  3. ! file, as its position marks the beginning of small data
  4. !
  5.     .seg    "data"
  6.     .global    _environ        ! first symbol in sdata        
  7. _environ:
  8.     .word    0
  9. !
  10. ! This variable is used in the DELAY macro.  5 is the right value for
  11. ! 68010's running 10MHz.  3 is the right value for 68020's running 16MHz
  12. ! with cache on.  (4x as fast at doing the delay loop.)  Other values
  13. ! should be empirically determined as needed.  Srt0.s sets this value
  14. ! based on the actual runtime environment encountered.
  15. !
  16. ! For a sunrise machine with no cache (16Mhz) the delay should be 4
  17. ! if the cache is on the delay can be 1
  18. !
  19. ! It's critical that the value be no SMALLER than required, e.g. the
  20. ! DELAY macro guarantees a MINIMUM delay, not a maximum.
  21. !
  22.     .seg    "data"
  23.     .global    _cpudelay
  24. _cpudelay:
  25.     .word    5            ! Multiplier for DELAY macro.
  26.  
  27.     .seg    "text"
  28.     .align    4
  29. !
  30. ! Startup code for standalone system
  31. !
  32. WINDOWSIZE = (16 * 4)
  33.  
  34.     .global    _end
  35.     .global    _edata
  36.     .global    _main
  37.     .global    __exit
  38.     .global    _startKernel
  39.     .global _romp
  40.     .global    start
  41. start:
  42.     save    %sp, -WINDOWSIZE, %sp    ! get a new window, leave room for args
  43.     call    1f            ! get the current pc into o7
  44.     nop                ! (where entry is currently located)
  45. 1:
  46.         ba      realStart
  47.         nop
  48.     .skip    (8192)
  49. realStart:
  50.     mov    %o7, %o0        ! save for later
  51.     sub    %o0, 4, %o0        ! point to first byte of prog
  52.     set    start+4,%o6        ! address of call instruction - above 
  53.     cmp    %o6, %o7        ! are they the same
  54. #if 0
  55.     be    start
  56. #else
  57.     be    go
  58. #endif
  59.     nop
  60.     set    _edata+4, %o2        ! end of program, inclusive, except bss
  61.     set     start, %o1        ! beginning of program
  62.     sub    %o2, %o1, %o2        ! size of program
  63.     !
  64.     ! check that the following copy won't write on itself
  65.     !
  66.     !add    %o7,%o2,%o5
  67.     !cmp    %o5,%o0    
  68.     !bg    cantreloc
  69.     !nop
  70.     !
  71.     ! copy program where it belongs
  72.     !
  73. 2:
  74.     ld    [%o0], %o3        ! read a word
  75.     add    %o0, 4, %o0            ! point to next src word
  76.     st    %o3, [%o1]        ! write a word
  77.     subcc    %o2, 4, %o2            ! check if done
  78.     bge    2b            ! if not loop
  79.     add    %o1, 4, %o1        ! delay slot, point to next dest word
  80.  
  81.     set    go, %g1        ! now that it is relocated, jump to it
  82.     jmp    %g1
  83.     nop
  84.     ! program is now relocated
  85. go:
  86.     ! we should turn on cache at least by now
  87.     set    _romp, %o2
  88.     st    %i0, [%o2]
  89.     set    _end+4, %o2        ! end of bss
  90.     set    _edata, %o0        ! beginning of bss
  91.     sub    %o2, %o0, %o2        ! size of bss
  92.     ! zero the bss
  93. 1:
  94.     subcc    %o2, 1,    %o2            ! loop to zero bss
  95.     st    %g0,[%o0]
  96.     bnz    1b
  97.     add    %o0, 4, %o0
  98.  
  99.     ! general startup code
  100.     set    (_environ+0x1000), %g7    ! 1st global register (etext + 4K)
  101.     set    0x2000, %g6        ! 8k
  102.     add    %g7, %g6, %g6        ! 2nd global register (1st global + 8K)
  103.     ld    [%sp + WINDOWSIZE], %o0    ! argc
  104.     add    %sp, WINDOWSIZE + 4, %o1! argv
  105.     sll    %o0, 2, %o2        ! argc * sizeof (int)
  106.     add    %o2, 4, %o2        ! skip 0 at end of arg ptrs
  107.     add    %o1, %o2, %o2        ! environ ptr
  108.     call    _main
  109.     st    %o2, [%g7 + -0x1000]    ! store 1st word of sdata %ad(_environ)
  110.     nop
  111. #ifdef notdef
  112.     call    _exit            ! exit(0)
  113. #endif
  114.     mov    0, %o0            ! delay slot
  115. __exit:
  116.     ret                ! ret to prom
  117.     restore
  118. _romp:
  119.     .word 0
  120. _startKernel:
  121.     mov    %o0, %g1
  122.     mov    %o1, %i0        ! preserve some arguments
  123.     mov    %o2, %i1        ! preserve some arguments
  124.     jmp    %g1
  125.     restore
  126.